僕の頁 <SASと臨床試験と雑談と>

徒然なるままにSAS暮らし

----

スポンサーサイト  

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

Posted on --/--/-- --. --:-- [edit]

CM: --
TB: --

0402

グラフの「にょろ」  

入社1年目に怖い先輩から「SASでグラフににょろ出されへんのか?」と
脅迫され、「すいません、私の知る限りSASでは無理です・・・。」と
回答したことが昨日のように思い出されます。さて、「にょろ」って何?
て話ですが、ここで言う「にょろ」とは、グラフの軸を途中で省略する
波線のことで、英語では「broken axis」と言うみたいです。まーとにかく
SAS9.4の事例を見てみましょう。「にょろ」の出力は、GTLの中のlinearoptsの
includerangesオプションで実現できます。GTLの細かい話は置いておいて、
以下の例では縦軸に「にょろ」を出力しています。


*** テストデータ作成(地域ごとの売り上げ) ;
data TEST ;
input REGION $ 1-13 SALES ;
format SALES dollar10. ;
cards;
Asia 50000
EU 60000
North America 80000
South America 5000
Africa 3000
;
run ;
*** GTL(includerangeで範囲を指定) ;
proc template;
define statgraph broken_axis ;
begingraph;
entrytitle 'Broken Axis (Y-axis)';
layout overlay
/ xaxisopts=(display=(ticks tickvalues))
yaxisopts=(display=(ticks tickvalues) griddisplay=off
linearopts=(includeranges=(0-10000 40000-90000)
tickvaluelist=(5000 50000 60000 70000 80000 90000))) ;
barchart category=REGION response=SALES ;
endlayout;
endgraph;
end;
run;
*** 出力 ;
proc sgrender data=TEST template=broken_axis ;
run ;

結果は以下になります。出てますね、「にょろ」♪
いや~、懐かしいやり取りを思い出しました。
broken_axis.png

使うことはないでしょうが、3個以上の場合でも複数の「にょろ」を
出力できます。少しテストデータを変えて実行します。
*** テストデータ作成(地域ごとの売り上げ) ;
data TEST2 ;
input REGION $ 1-13 SALES ;
format SALES dollar10. ;
cards;
Asia 50000
EU 90000
North America 100000
South America 5000
Africa 3000
;
run ;

*** GTL(includerangeで3個以上の範囲を指定) ;
proc template;
define statgraph broken_axis ;
begingraph;
entrytitle 'Broken Axis (Y-axis)';
layout overlay
/ xaxisopts=(display=(ticks tickvalues))
yaxisopts=(display=(ticks tickvalues) griddisplay=off
linearopts=(includeranges=(0-10000 40000-60000 80000-110000)
tickvaluelist=(5000 50000 80000 90000 100000))) ;
barchart category=REGION response=SALES ;
endlayout;
endgraph;
end;
run;
*** 出力 ;
proc sgrender data=TEST2 template=broken_axis ;
run ;

結果は以下になります。SAS9.4恐るべしです。
broken_axis2.png

スポンサーサイト

Posted on 2014/04/02 Wed. 00:47 [edit]

CM: 2
TB: 0

プロフィール

最新記事

最新コメント

最新トラックバック

月別アーカイブ

カテゴリ

訪れた人

▲Page top

上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。